четвер, 12 серпня 2010 р.

AutoHotKey

Ну буду разводить полемику на тему большего количества настроек интерфейса в X-ах по-сравнению с Windows, а расскажу об одной небольшой, но очень полезной программке, которая как раз и позволяет мне иметь дополнительные возможности в интерфейсе Windows.
Сия чудная програмка называется AutoHotKey.
При запуске она радостно прячется в трей и вообще не мешает, но реагирует на определённые события от мыши или клавиатуры и выполняет какие-либо действия.
Вот об этих событиях и действиях далее и пойдёт речь.

Проще всего привести свой конфигурационный файлик и описать, что каждая из строчек делает.

Итак, поехали!
Начало (в принципе тут ничего существенного: константы, мелкие настройки):


WS_EX_APPWINDOW = 0x40000
WS_EX_TOOLWINDOW = 0x80
GW_OWNER = 4

SetTitleMatchMode RegEx
DetectHiddenWindows, On
SetWinDelay,2


Далее идут события от клавиатуры, Win-Z минимизирует окно:


#z::PostMessage, 0x112, 0xF020,,,A ; 0x112 = WM_SYSCOMMAND, 0xF020 = SC_MINIMIZE


Win-X максимизирует окно:


#x::
WinGet MX, MinMax, A
If MX
WinRestore, A
Else
WinMaximize, A
return


Win-minus (-) закроет приложение:

#-::WinClose, A


Win-PgDown добавить прозрачности окну (заглянуть под окно), но я этой функцией не пользуюсь, да и под Win7, похоже, не совсем работает:

#PgDn::
WinGet, list, List
loop, %list%
{
wid := list%A_Index%
WinGet, es, ExStyle, ahk_id %wid%
if ( ( ! DllCall( "GetWindow", "uint", wid, "uint", GW_OWNER ) and ! ( es & WS_EX_TOOLWINDOW ) )
or ( es & WS_EX_APPWINDOW ) )
WinSet, Transparent, 10, ahk_id %wid%
}
return


Win-PgUp, соответственно, уберёт прозрачность:

#PgUp::
WinGet, list, List
loop, %list%
{
wid := list%A_Index%
WinGet, es, ExStyle, ahk_id %wid%
if ( ( ! DllCall( "GetWindow", "uint", wid, "uint", GW_OWNER ) and ! ( es & WS_EX_TOOLWINDOW ) )
or ( es & WS_EX_APPWINDOW ) )
WinSet, Transparent, 255, ahk_id %wid%
}
return


Объявляем пару функций:

WMove(dx, dy) {
WinGetPos, X, Y, , , A
WinMove, A, , (X + dx), (Y + dy)
}

WResize(dw, dh) {
WinGetPos, , , W, H, A
WinMove, A, , , , (W + dw), (H + dh)
}


Следующие сочетания клавиш перемещают или изменяют размер окна, к примеру Win-Up подвинет окно вверх на 50 пикселей, Shift-Right увеличит ширину на 50 пикселей (модификаторы: # — Win, + &mdash Shift, ^ — Control), не работает с putty (но с ним ничего не работает — он полностью сам управляет окном и перекрывает системные события):

+^#Up::WResize(0, -10)
+^#Down::WResize(0, 10)
+^#Left::WResize(-10, 0)
+^#Right::WResize(10, 0)
+#Up::WResize(0, -50)
+#Down::WResize(0, 50)
+#Left::WResize(-50, 0)
+#Right::WResize(50, 0)
^#Up::WMove(0, -10)
^#Down::WMove(0, 10)
^#Left::WMove(-10, 0)
^#Right::WMove(10, 0)
#Up::WMove(0, -50)
#Down::WMove(0, 50)
#Left::WMove(-50, 0)
#Right::WMove(50, 0)


Как оказалось для меня, управление окнами с клавиатуры — очень полезная вещь!

Далее запуск приложений: Win-S — Far Manager и т.д.

#s::Run, "C:\home\share\quicklaunch\FAR manager.lnk"
#v::Run, gvim.exe
#j::Run, c:\home\bin\eject.exe
#c::Run, c:\windows\system32\calc.exe


В давние времена я пользовался Thunderbird:

#m::
SetTitleMatchMode, 2
Process, Exist, Thunderbird.exe
if %ErrorLevel% = 0
{
Run, c:\usr\thunderbird\thunderbird.exe
WinWait, Thunderbird
WinShow, Thunderbird
}
;#WinActivateForce
IfWinNotActive, Thunderbird
{
WinActivate, Thunderbird,
;WinWaitActive, Thunderbird,
;WinActivateBottom, Thunderbird
;WinWaitActive, .* - Thunderbird
}
return


.. и Оперой:

#w::
IfWinExist, Opera
WinActivate
else
Run, c:\Program Files\Opera\opera.exe
return


Запуск Outlook (или из трея вытащить), плюс Win-Ctrl-t покажет окно для ввода новой задачи:

#o::
IfWinExist, .* - Microsoft Outlook
WinActivate
else
Run, "C:\Program Files\Microsoft Office\Office12\OUTLOOK.EXE"
return
^#t::Run, "C:\Program Files\Microsoft Office\Office12\OUTLOOK.EXE" -c ipm.task


Win-y запустит (или вытащит — грубо, но работает) Skype из трея (хотя сам Skype клавиатурой практически не управляется):

#y::Run, C:\Program Files\Skype\Phone\Skype.exe


Для размонтирования флешек или внешних винтов использую USB Disk Eject (Win-u)

#u::
Process, Exist, USB_Disk_Eject.exe
if %ErrorLevel% = 0
{
Run, C:\usr\USB-disk-eject\USB_Disk_Eject.exe
WinWait, Safely Remove USB Disks
WinShow, Safely Remove USB Disks
}
IfWinNotActive, Safely Remove USB Disks
{
WinActivate, Safely Remove USB Disks
}
return


Который теперь спокойно закрывается по Escape (а не Alt-F4):

~Escape::
IfWinActive, Safely Remove USB Disks
WinClose
return


Работа в X-Window быстро меня приучила к использованию Caps-Lock для переключения раскладок, и стандартные Alt-Shift или Ctrl-Shift в Windows меня абсолютно не привлекают. Далее код, который переключает состояние Caps Lock по нажатию Shift-CapsLock, а раскладки переключает просто по CapsLock:

;; Toggle CapsLock state on Shift-CapsLock
+CapsLock::
state := GetKeyState("Capslock", "T")
if state
SetCapsLockState, Off
else
SetCapsLockState, On
return

;; Switch language on CapsLock
CapsLock::
SetStoreCapslockMode, Off
Send {LAlt down}{Shift}{LAlt up}
return


Опять же, работа в X-Window также приучила к тому, что намного быстрее перетащить окно, если зажать Alt, а затем левую кнопку мыши, если курсор внутри этого окна, чем пытаться навести курсор мыши на заголовок окна, а также Alt плюс правая кнопка мыши будет менять размер этого окна:

; http://www.autohotkey.com/docs/scripts/EasyWindowDrag_(KDE).htm

CoordMode,Mouse
return

!LButton::
CoordMode, Mouse ; Switch to screen/absolute coordinates.
MouseGetPos, EWD_MouseStartX, EWD_MouseStartY, EWD_MouseWin
WinGetPos, EWD_OriginalPosX, EWD_OriginalPosY,,, ahk_id %EWD_MouseWin%
SetTimer, EWD_WatchMouse, 10 ; Track the mouse as the user drags it.
return

EWD_WatchMouse:
GetKeyState, EWD_LButtonState, LButton, P
if EWD_LButtonState = U ; Button has been released, so drag is complete.
{
SetTimer, EWD_WatchMouse, off
return
}
GetKeyState, EWD_EscapeState, Escape, P
if EWD_EscapeState = D ; Escape has been pressed, so drag is cancelled.
{
SetTimer, EWD_WatchMouse, off
WinMove, ahk_id %EWD_MouseWin%,, %EWD_OriginalPosX%, %EWD_OriginalPosY%
return
}
; Otherwise, reposition the window to match the change in mouse coordinates
; caused by the user having dragged the mouse:
CoordMode, Mouse
MouseGetPos, EWD_MouseX, EWD_MouseY
WinGetPos, EWD_WinX, EWD_WinY,,, ahk_id %EWD_MouseWin%
SetWinDelay, -1 ; Makes the below move faster/smoother.
WinMove, ahk_id %EWD_MouseWin%,, EWD_WinX + EWD_MouseX - EWD_MouseStartX, EWD_WinY + EWD_MouseY - EWD_MouseStartY
EWD_MouseStartX := EWD_MouseX ; Update for the next timer-call to this subroutine.
EWD_MouseStartY := EWD_MouseY
return

!RButton::
CoordMode, Mouse
MouseGetPos, Resize_PrevX, Resize_PrevY, Resize_Win
WinGetPos, Resize_OrigX, Resize_OrigY, Resize_OrigW, Resize_OrigH, ahk_id %Resize_Win%
SetTimer, Resize_Watch, 10
return

Resize_Watch:
GetKeyState, Resize_RB, RButton, P
if Resize_RB = U
{
SetTimer, Resize_Watch, off
return
}
GetKeyState, Resize_Esc, Escape, P
if Resize_Esc = D
{
SetTimer, Resize_Watch, off
WinMove, ahk_id %Resize_Win%,, %Resize_OrigX%, %Resize_OrigY%, %Resize_OrigW%, %Resize_OrigH%
return
}
CoordMode, Mouse
MouseGetPos, Resize_MouseX, Resize_MouseY
WinGetPos, ,, Resize_WinW, Resize_WinH, ahk_id %Resize_Win%
SetWinDelay, -1
WinMove, ahk_id %Resize_Win%,, Resize_OrigX, Resize_OrigY, Resize_WinW + Resize_MouseX - Resize_PrevX, Resize_WinH + Resize_MouseY - Resize_PrevY
Resize_PrevX := Resize_MouseX
Resize_PrevY := Resize_MouseY
return


Вот собственно и всё ;)
Очень много полезных скриптов можно найти в интернете — дерзайте!

Немає коментарів:

Дописати коментар